r1318 - in trunk/oe/packages/linux: . linux-gta01

laforge at sita.openmoko.org laforge at sita.openmoko.org
Sat Mar 10 23:48:26 CET 2007


Author: laforge
Date: 2007-03-10 23:48:26 +0100 (Sat, 10 Mar 2007)
New Revision: 1318

Added:
   trunk/oe/packages/linux/linux-gta01/defconfig-2.6.20.2-fic-gta01
   trunk/oe/packages/linux/linux-gta01_2.6.20.2.bb
Modified:
   trunk/oe/packages/linux/gta01-kernel_2.6.bb
Log:
* add 2.6.20.2 kernel


Modified: trunk/oe/packages/linux/gta01-kernel_2.6.bb
===================================================================
--- trunk/oe/packages/linux/gta01-kernel_2.6.bb	2007-03-10 22:08:06 UTC (rev 1317)
+++ trunk/oe/packages/linux/gta01-kernel_2.6.bb	2007-03-10 22:48:26 UTC (rev 1318)
@@ -1 +1 @@
-require linux-gta01_2.6.20.1.bb
+require linux-gta01_2.6.20.2.bb

Copied: trunk/oe/packages/linux/linux-gta01/defconfig-2.6.20.2-fic-gta01 (from rev 1315, trunk/oe/packages/linux/linux-gta01/defconfig-2.6.20.1-fic-gta01)

Added: trunk/oe/packages/linux/linux-gta01_2.6.20.2.bb
===================================================================
--- trunk/oe/packages/linux/linux-gta01_2.6.20.2.bb	2007-03-10 22:08:06 UTC (rev 1317)
+++ trunk/oe/packages/linux/linux-gta01_2.6.20.2.bb	2007-03-10 22:48:26 UTC (rev 1318)
@@ -0,0 +1,103 @@
+DESCRIPTION = "2.6 Linux Development Kernel for FIC Neo1973 (GTA01)"
+SECTION = "kernel"
+AUTHOR = "Harald Welte <laforge at openmoko.org>"
+HOMEPAGE = "N/A"
+LICENSE = "GPL"
+DEPENDS += "quilt-native uboot-gta01"
+MOKOR = "moko8"
+PR = "${MOKOR}-r1"
+
+VANILLA_VERSION = "2.6.20.2"
+
+inherit kernel
+
+FILESDIR = "${@os.path.dirname(bb.data.getVar('FILE',d,1))}/linux-gta01"
+
+##############################################################
+# source and patches
+#
+SRC_URI = "http://ftp.de.kernel.org/pub/linux/kernel/v2.6/linux-${VANILLA_VERSION}.tar.bz2 \
+           svn://svn.openmoko.org/trunk/src/target/kernel;module=patches;proto=https \
+           file://defconfig-${VANILLA_VERSION}-${MACHINE}"
+S = "${WORKDIR}/linux-${VANILLA_VERSION}"
+
+##############################################################
+# kernel image resides on a seperate flash partition (for now)
+#
+FILES_kernel-image = ""
+ALLOW_EMPTY = "1"
+
+COMPATIBLE_HOST = "arm.*-linux"
+COMPATIBLE_MACHINE = 'fic-gta01'
+
+CMDLINE_CON = "console=ttySAC0,115200n8"
+#CMDLINE_ROOT = "root=/dev/mmcblk0p1 rootfstype=ext3 rootdelay=5"
+# uncomment if you want to boot over NFS
+#CMDLINE_ROOT = "root=/dev/nfs nfsroot=192.168.1.10:/export/opie-image rootdelay=5 3"
+# uncomment to enable dyntick
+#CMDLINE_OTHER = "dyntick=enable"
+CMDLINE_DEBUG = '${@base_conditional("DISTRO_TYPE", "release", "quiet", "debug",d)}'
+CMDLINE_IP = "ip=192.168.1.2:192.168.1.10:192.168.1.10:255.255.255.0:ezx:usb0:off"
+CMDLINE = "${CMDLINE_CON} ${CMDLINE_ROOT} ${CMDLINE_IP} ${CMDLINE_ROTATE} ${CMDLINE_OTHER} ${CMDLINE_DEBUG}"
+
+###############################################################
+# module configs specific to this kernel
+#
+module_autoload_ohci-hcd = "ohci-hcd"
+module_autoload_g_ether = "g_ether"
+#module_autoload_snd-pcm-oss = "snd-pcm-oss"
+#module_autoload_snd-soc-corgi_c7x0 = "snd-soc-s3c24xx"
+
+do_prepatch() {
+        mv ${WORKDIR}/patches ${S}/patches && cd ${S} && quilt push -av
+        rm -Rf patches .pc
+}
+
+do_configure() {
+	#install -m 0644 ${WORKDIR}/logo_linux_clut224.ppm drivers/video/logo/logo_linux_clut224.ppm
+
+	if [ ! -e ${WORKDIR}/defconfig-${VANILLA_VERSION}-${MACHINE} ]; then
+		die "No default configuration for ${MACHINE} available."
+	fi
+
+	echo "CONFIG_CMDLINE=\"${CMDLINE}\"" >> ${S}/.config
+
+	if [ "${TARGET_OS}" == "linux-gnueabi" ]; then
+		echo "CONFIG_AEABI=y"                   >> ${S}/.config
+		echo "CONFIG_OABI_COMPAT=y"             >> ${S}/.config
+	else 
+		echo "# CONFIG_AEABI is not set"        >> ${S}/.config
+		echo "# CONFIG_OABI_COMPAT is not set"  >> ${S}/.config
+	fi
+
+	sed -e '/CONFIG_AEABI/d' \
+	    -e '/CONFIG_OABI_COMPAT=/d' \
+	    -e '/CONFIG_CMDLINE=/d' \
+	    -e '/CONFIG_MTD_MTDRAM_SA1100=/d' \
+	    -e '/CONFIG_MTDRAM_TOTAL_SIZE=/d' \
+	    -e '/CONFIG_MTDRAM_ERASE_SIZE=/d' \
+	    -e '/CONFIG_MTDRAM_ABS_POS=/d' \
+	    '${WORKDIR}/defconfig-${VANILLA_VERSION}-${MACHINE}' >>'${S}/.config'
+
+	yes '' | oe_runmake oldconfig
+}
+
+###############################################################
+# put into deploy directory and append u-boot header
+#
+do_deploy() {
+	install -d ${DEPLOY_DIR_IMAGE}
+	install -m 0644 arch/${ARCH}/boot/${KERNEL_IMAGETYPE} ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGETYPE}-${PV}-${PR}-${MACHINE}.bin
+	tar -cvzf ${DEPLOY_DIR_IMAGE}/modules-${KERNEL_RELEASE}-${PR}-${MACHINE}.tgz -C ${D} lib
+	arm-linux-objcopy -O binary -R .note -R .comment -S vmlinux linux.bin
+	rm -f linux.bin.gz
+	gzip -9 linux.bin
+	${STAGING_BINDIR_NATIVE}/uboot-mkimage -A arm -O linux -T kernel -C gzip -a 30008000 -e 30008000 -n "OpenMoko Kernel Image Neo1973(GTA01)" -d linux.bin.gz ${DEPLOY_DIR_IMAGE}/uImage-${PV}-${PR}-${MACHINE}.bin
+	rm -f linux.bin.gz
+}
+
+do_deploy[dirs] = "${S}"
+
+addtask prepatch before do_patch after do_unpack
+addtask deploy before do_package after do_install
+





More information about the commitlog mailing list