r225 - in trunk/oe/packages: linux tasks uboot


Wed Nov 15 14:40:25 CET 2006


Author: 
Date: 2006-11-15 13:40:25 +0000 (Wed, 15 Nov 2006)
New Revision: 225

Added:
   trunk/oe/packages/linux/linux-qt2410_2.6.17.14.bb
   trunk/oe/packages/uboot/uboot-qt2410_0.0+cvs20061030.bb
Modified:
   trunk/oe/packages/tasks/task-openmoko.bb
Log:
oe: add new versions for kernel and uboot for qt2410


Added: trunk/oe/packages/linux/linux-qt2410_2.6.17.14.bb
===================================================================
--- trunk/oe/packages/linux/linux-qt2410_2.6.17.14.bb	2006-11-15 13:39:03 UTC (rev 224)
+++ trunk/oe/packages/linux/linux-qt2410_2.6.17.14.bb	2006-11-15 13:40:25 UTC (rev 225)
@@ -0,0 +1,100 @@
+DESCRIPTION = "2.6 Linux Development Kernel for Armzone QT2410"
+SECTION = "kernel"
+AUTHOR = "Harald Welte <hwelte at hmw-consulting.de>"
+HOMEPAGE = "N/A"
+LICENSE = "GPL"
+DEPENDS += "quilt-native uboot-qt2410"
+PR = "r2"
+
+inherit kernel
+
+FILESDIR = "${@os.path.dirname(bb.data.getVar('FILE',d,1))}/linux-qt2410"
+HWSRC = "http://people.gta01.hmw-consulting.de/laforge/src/kernel/20060806"
+
+##############################################################
+# source and patches
+#
+SRC_URI = "http://ftp.de.kernel.org/pub/linux/kernel/v2.6/linux-2.6.17.14.tar.bz2 \
+           file://patches-2.6.17.7-fic1.tar.bz2 \
+	   file://udc-nomodule-misccr.patch;patch=1 \
+           file://defconfig-${MACHINE}"
+S = "${WORKDIR}/linux-2.6.17.14"
+
+##############################################################
+# kernel image resides on a seperate flash partition (for now)
+#
+FILES_kernel-image = ""
+ALLOW_EMPTY = "1"
+
+COMPATIBLE_HOST = "arm.*-linux"
+COMPATIBLE_MACHINE = 'armzone-qt2410'
+
+CMDLINE_CON = "console=ttySAC0,115200n8"
+#CMDLINE_ROOT = "root=/dev/mmcblk0p1 rootfstype=ext3 rootdelay=5"
+# uncomment if you want to boot over NFS
+#CMDLINE_ROOT = "root=/dev/nfs nfsroot=192.168.1.10:/export/opie-image rootdelay=5 3"
+# uncomment to enable dyntick
+#CMDLINE_OTHER = "dyntick=enable"
+CMDLINE_DEBUG = '${@base_conditional("DISTRO_TYPE", "release", "quiet", "debug",d)}'
+CMDLINE_IP = "ip=192.168.1.2:192.168.1.10:192.168.1.10:255.255.255.0:ezx:usb0:off"
+CMDLINE = "${CMDLINE_CON} ${CMDLINE_ROOT} ${CMDLINE_IP} ${CMDLINE_ROTATE} ${CMDLINE_OTHER} ${CMDLINE_DEBUG}"
+
+###############################################################
+# module configs specific to this kernel
+#
+#module_autoload_pxaficp_ir = "pxaficp_ir"
+#module_autoload_snd-pcm-oss = "snd-pcm-oss"
+
+do_prepatch() {
+        mv ${WORKDIR}/patches ${S}/patches && cd ${S} && quilt push -av
+        rm -Rf patches .pc
+}
+
+do_configure() {
+	#install -m 0644 ${WORKDIR}/logo_linux_clut224.ppm drivers/video/logo/logo_linux_clut224.ppm
+
+	if [ ! -e ${WORKDIR}/defconfig-${MACHINE} ]; then
+		die "No default configuration for ${MACHINE} available."
+	fi
+
+	echo "CONFIG_CMDLINE=\"${CMDLINE}\"" >> ${S}/.config
+
+	if [ "${TARGET_OS}" == "linux-gnueabi" ]; then
+		echo "CONFIG_AEABI=y"                   >> ${S}/.config
+		echo "CONFIG_OABI_COMPAT=y"             >> ${S}/.config
+	else 
+		echo "# CONFIG_AEABI is not set"        >> ${S}/.config
+		echo "# CONFIG_OABI_COMPAT is not set"  >> ${S}/.config
+	fi
+
+	sed -e '/CONFIG_AEABI/d' \
+	    -e '/CONFIG_OABI_COMPAT=/d' \
+	    -e '/CONFIG_CMDLINE=/d' \
+	    -e '/CONFIG_MTD_MTDRAM_SA1100=/d' \
+	    -e '/CONFIG_MTDRAM_TOTAL_SIZE=/d' \
+	    -e '/CONFIG_MTDRAM_ERASE_SIZE=/d' \
+	    -e '/CONFIG_MTDRAM_ABS_POS=/d' \
+	    '${WORKDIR}/defconfig-${MACHINE}' >>'${S}/.config'
+
+	yes '' | oe_runmake oldconfig
+}
+
+###############################################################
+# put into deploy directory and append u-boot header
+#
+do_deploy() {
+	install -d ${DEPLOY_DIR_IMAGE}
+	install -m 0644 arch/${ARCH}/boot/${KERNEL_IMAGETYPE} ${DEPLOY_DIR_IMAGE}/${KERNEL_IMAGETYPE}-${PV}-${MACHINE}-${DATETIME}.bin
+	tar -cvzf ${DEPLOY_DIR_IMAGE}/modules-${KERNEL_RELEASE}-${MACHINE}.tgz -C ${D} lib
+	arm-linux-objcopy -O binary -R .note -R .comment -S vmlinux linux.bin
+	rm -f linux.bin.gz
+	gzip -9 linux.bin
+	uboot-mkimage -A arm -O linux -T kernel -C gzip -a 30008000 -e 30008000 -n "Kernel Image QT2410" -d linux.bin.gz ${DEPLOY_DIR_IMAGE}/uImage-${PV}-${MACHINE}-${DATETIME}.bin
+	rm -f linux.bin.gz
+}
+
+do_deploy[dirs] = "${S}"
+
+addtask prepatch before do_patch after do_unpack
+addtask deploy before do_package after do_install
+

Modified: trunk/oe/packages/tasks/task-openmoko.bb
===================================================================
--- trunk/oe/packages/tasks/task-openmoko.bb	2006-11-15 13:39:03 UTC (rev 224)
+++ trunk/oe/packages/tasks/task-openmoko.bb	2006-11-15 13:40:25 UTC (rev 225)
@@ -162,6 +162,7 @@
   udev-utils \
   usbutils \
   uucp \
+  cu \
 "
 
 #

Added: trunk/oe/packages/uboot/uboot-qt2410_0.0+cvs20061030.bb
===================================================================
--- trunk/oe/packages/uboot/uboot-qt2410_0.0+cvs20061030.bb	2006-11-15 13:39:03 UTC (rev 224)
+++ trunk/oe/packages/uboot/uboot-qt2410_0.0+cvs20061030.bb	2006-11-15 13:40:25 UTC (rev 225)
@@ -0,0 +1,41 @@
+DESCRIPTION = "U-boot bootloader w/ armzone qt2410 support"
+SECTION = "bootloader"
+PRIORITY = "optional"
+LICENSE = "GPL"
+SRCDATE := "${PV}"
+PR = "r0"
+
+PROVIDES = "virtual/bootloader"
+S = "${WORKDIR}/git"
+
+SRC_URI = "git://www.denx.de/git/u-boot.git/;protocol=git \
+	   file://u-boot-20061030-qt2410-gta01.patch;patch=1 \
+	   file://qt2410_*.h"
+
+EXTRA_OEMAKE = "CROSS_COMPILE=${TARGET_PREFIX}"
+TARGET_LDFLAGS = ""
+UBOOT_MACHINE = "qt2410_config"
+
+inherit base
+
+do_compile () {
+	for type in nand  ram
+	do
+		install -m 0644 ${WORKDIR}/qt2410_${type}.h include/configs/qt2410.h
+		oe_runmake ${UBOOT_MACHINE}
+		oe_runmake all
+		mv u-boot.bin u-boot_$type.bin
+	done
+}
+
+do_deploy () {
+	install -d ${DEPLOY_DIR_IMAGE}
+	for type in nand ram
+	do
+		install ${S}/u-boot_$type.bin ${DEPLOY_DIR_IMAGE}/u-boot_$type-${MACHINE}-${DATETIME}.bin
+	done
+	install -m 0755 tools/mkimage ${STAGING_BINDIR}/uboot-mkimage
+}
+
+do_deploy[dirs] = "${S}"
+addtask deploy before do_build after do_compile





More information about the commitlog mailing list